DELPHI AREA :: View topic - Perfect looping possible?

through

[^/[Print]\]

DELPHI AREA -> DELPHI AREA's Products

#1: Perfect looping possible? Author: Cluq,

Posted: 14/11/04 13:00
—
Hi

I'm using the AudioPlayer to play a looping wave file. The looping works, but not perfectly. There is a very small silence before the wave starts over again and I would like it to loop without that silence. I have checked the wave file - it loops perfectly in SoundForge.

This is the simple code I've been using:

-----------------
type
TForm1 = class(TForm)
CheckBox1: TCheckBox;
AudioPlayer1: TAudioPlayer;
procedure AudioPlayer1Deactivate(Sender: TObject);
procedure CheckBox1Click(Sender: TObject);
private
{ Private declarations }
public
{ Public declarations }
end;

var
Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.AudioPlayer1Deactivate(Sender: TObject);
begin
AudioPlayer1.Active := checkbox1.Checked;
end;

procedure TForm1.CheckBox1Click(Sender: TObject);
begin
AudioPlayer1.Active := checkbox1.Checked;
end;
------------

Have any of you a better idea to get perfect looping?

Best regards,
Cluq.

#2: Author: Kambiz, Location: Tehran, Iran

Posted: 14/11/04 16:27
—
Hi,

You can use LiveAudioPlayer. In the event hanlder for supplying the wave data, you can specify the number of loops.

Cheers,
Kambiz

#3: Author: Cluq,

Posted: 15/11/04 08:32
—
Ok, thank you very much.

I've been looking at the LiveAudioPlayer Demo (the receiver part). I get the part that the variable WaveFormat is where the actual wave data is loaded into, right? But how would you go about loading wave data from a local wave-file on your harddrive?

/Cluq

#4: Author: Kambiz, Location: Tehran, Iran

Posted: 15/11/04 09:12
—
Use a TWaveStorage instance.

Code:

procedure TForm1.LiveAudioPlayer1Format(Sender: TObject;
out pWaveFormat: PWaveFormatEx; var FreeIt: Boolean);
begin
FreeIt := False;
pWaveFormat := WaveStorage1.Wave.WaveFormat;
end;

function TForm1.LiveAudioPlayer1DataPtr(Sender: TObject;
out Buffer: Pointer; var NumLoops: Cardinal;
var FreeIt: Boolean): Cardinal;
begin
FreeIt := False;
NumLoops := $FFFFFFFF; // infinite
Buffer := WaveStorage1.Wave.Data;
Result := WaveStorage1.Wave.DataSize;
end;

By the way, set LiveAudioPlayer.BufferCount to 1 and LiveAudioPlayer.BufferInternally to False.

#5: Author: Cluq,

Posted: 15/11/04 12:14
—
Ahh...of course...I'll be trying that out...

Btw, if I get positive results from this, I will most likely use this in my freeware game I'm writing... It is almost done, except for the sound. I have been using another unit for playing sound, but it had memory leaks and other crappy things wrong with it, so I'm looking for a better unit.

But this is looking quite nice so far...

/Cluq

#6: Author: Cluq,

Posted: 16/11/04 09:24
—
I have now done exactly as you said, but the sound doesn't loop. It only play once... LiveAudioPlayer.Active remains true - there is just silence...

The audio file is PCM 44,100 kHz, 16bit, Stereo...

#7: Author: Cluq,

Posted: 17/11/04 11:38
—
Have I found a bug? Wink

#8: Author: Kambiz, Location: Tehran, Iran

Posted: 24/11/04 12:02
—
Yes, there's a bug. Open the WaveOut.pas file and look for

Code:

WHDR_BEGINLOOP or WHDR_BEGINLOOP

then replace it with

Code:

WHDR_BEGINLOOP or WHDR_ENDLOOP

By the way, you can leave the NumLoops as zero. Because when a buffer finished, the OnDataPtr event will be raised once more, until your return zero as result. If you set the NumLoops parameter, in the next call of the event you should return zero. So, my prevoius code is wrong.

Solution 1:

Code:

LiveAudioPlayer1.BufferInternally := False;

procedure TForm1.LiveAudioPlayer1Format(Sender: TObject;
out pWaveFormat: PWaveFormatEx; var FreeIt: Boolean);
begin
FreeIt := False;
pWaveFormat := WaveStorage1.Wave.WaveFormat;
end;

function TForm1.LiveAudioPlayer1DataPtr(Sender: TObject;
out Buffer: Pointer; var NumLoops: Cardinal;
var FreeIt: Boolean): Cardinal;
begin
FreeIt := False;
Buffer := WaveStorage1.Wave.Data;
Result := WaveStorage1.Wave.DataSize;
end;

Solution 2:

Code:

var
AlreadyFed: Boolean = False;

LiveAudioPlayer1.BufferInternally := False;

procedure TForm1.LiveAudioPlayer1Format(Sender: TObject;
out pWaveFormat: PWaveFormatEx; var FreeIt: Boolean);
begin
FreeIt := False;
pWaveFormat := WaveStorage1.Wave.WaveFormat;
end;

function TForm1.LiveAudioPlayer1DataPtr(Sender: TObject;
out Buffer: Pointer; var NumLoops: Cardinal;
var FreeIt: Boolean): Cardinal;
begin
if not AlreadyFed then
begin
FreeIt := False;
NumLoops := $FFFFFFF; // Infinite
Buffer := WaveStorage1.Wave.Data;
Result := WaveStorage1.Wave.DataSize;
AlreadyFed := True;
end
else
Result := 0;
end;

I'm sorry for being so late.

#9: Author: cozturk, Location: Istanbul - Turkiye

Posted: 07/11/05 12:28
—
when I load a stream from a file the loop is excellent.
unfortunately my stream is not static. For example
Buffer := filebuf4.Memory;
Result := filebuf4.Size;
NumLoops := $FFFFFFF; // Infinite
yes it plays continuous. But I need to clear the stream and load new data. To playing live audio stream which comes from a hardware

But it can not be done this when player loops .

If It plays the stream for once only, how can I load new data ? LiveAudioPlayer disable, and load new data and Enable again? It can be interrupted.

Is it possible to modify TAudioRedirector to fed with my stream?

#10: Author: Kambiz, Location: Tehran, Iran

Posted: 07/11/05 13:38
—
cozturk,

There was a missing method in TLiveAudioPlayer for breaking the loop. I added it (BreakLoop), and you can download the update from the site.

After calling the BreakLoop method, the player continues with the next buffer if any.

Here is a sample (suppose all waves are same format):

Code:

object Form1: TForm1
Left = 192
Top = 114
Width = 696
Height = 480
Caption = 'Form1'
Color = clBtnFace
Font.Charset = DEFAULT_CHARSET
Font.Color = clWindowText
Font.Height = -11
Font.Name = 'MS Sans Serif'
Font.Style = []
OldCreateOrder = False
PixelsPerInch = 96
TextHeight = 13
object CheckBox1: TCheckBox
Left = 96
Top = 24
Width = 97
Height = 17
Caption = 'Active'
TabOrder = 0
OnClick = CheckBox1Click
end
object Button1: TButton
Left = 208
Top = 24
Width = 75
Height = 25
Caption = 'Break Loop'
TabOrder = 1
OnClick = Button1Click
end
object LiveAudioPlayer1: TLiveAudioPlayer
PCMFormat = Stereo16bit22050Hz
BufferInternally = False
OnActivate = LiveAudioPlayer1Activate
OnDeactivate = LiveAudioPlayer1Deactivate
OnDataPtr = LiveAudioPlayer1DataPtr
Left = 40
Top = 64
end
object WaveCollection1: TWaveCollection
Waves = <
item
Name = 'chimes'
Data = {
// Data is removed to simplify the view...
}
end
item
Name = 'ding'
Data = {
// Data is removed to simplify the view...
}
end>
Left = 40
Top = 16
end
end

Code:

unit Unit1;

interface

uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
Dialogs, mmSystem, WaveUtils, WaveIO, WaveOut, WavePlayers, WaveStorage,
StdCtrls;

type
TForm1 = class(TForm)
LiveAudioPlayer1: TLiveAudioPlayer;
CheckBox1: TCheckBox;
WaveCollection1: TWaveCollection;
Button1: TButton;
function LiveAudioPlayer1DataPtr(Sender: TObject; out Buffer: Pointer;
var NumLoops: Cardinal; var FreeIt: Boolean): Cardinal;
procedure CheckBox1Click(Sender: TObject);
procedure LiveAudioPlayer1Activate(Sender: TObject);
procedure LiveAudioPlayer1Deactivate(Sender: TObject);
procedure Button1Click(Sender: TObject);
private
{ Private declarations }
public
{ Public declarations }
end;

var
Form1: TForm1;

implementation

{$R *.dfm}

function TForm1.LiveAudioPlayer1DataPtr(Sender: TObject;
out Buffer: Pointer; var NumLoops: Cardinal;
var FreeIt: Boolean): Cardinal;
begin
FreeIt := False;
if (Tag >= 0) and (Tag < WaveCollection1.Waves.Count) then
begin
Buffer := WaveCollection1.Waves[Tag].Wave.Data;
Result := WaveCollection1.Waves[Tag].Wave.DataSize;
NumLoops := $FFFFFFFF;
Tag := Tag + 1;
end
else
begin
Buffer := nil;
Result := 0;
end;
end;

procedure TForm1.CheckBox1Click(Sender: TObject);
begin
LiveAudioPlayer1.Active := CheckBox1.Checked;
end;

procedure TForm1.LiveAudioPlayer1Activate(Sender: TObject);
begin
Tag := 0;
CheckBox1.Checked := True;
end;

procedure TForm1.LiveAudioPlayer1Deactivate(Sender: TObject);
begin
CheckBox1.Checked := False;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
LiveAudioPlayer1.BreakLoop;
end;

end.

Cheers

#11: Author: cozturk, Location: Istanbul - Turkiye

Posted: 10/11/05 13:00
—
thanks. I tested your demo and understood that:
We must load the next buffer before calling the BreakLoop method.
Here is example(mentioned above) to easy testing or modifiying for other members:
http://s6.ultrashare.net/hosting/fs/94708f65b808b2c9/

I wish www.delphiarea.com have Project(or examples) Sharing Area

DELPHI AREA -> DELPHI AREA's Products

output generated using printer-friendly topic mod. All times are GMT

Page 1 of 1